Creating a recipe

Specify the source location

• Specify SRC_URI from git (git2 fetcher):

  SRC_URI = "git://github.com/wb2osz/direwolf.git;protocol=https;branch=master \
          "
  SRCREV = "a1e2d1c3a88723e41efaf44a10f6374e6dfdd8df"
  S = "${WORKDIR}/git"
  

• Specify SRC_URI from http/https (http fetcher):

  SRC_URI = "http://www.w1hkj.com/files/fldigi/fldigi-4.1.08.tar.gz \
          "
  SRC_URI[md5sum] = "9a6e4ccfaeb5e8d9fe19bd6020d8ca83"
  SRC_URI[sha256sum] = "004b54fa4ff03c85e088bf1706270db5f3976afcaaf1003b4d6d3b0ef8007349"
  

• Specify SRC_URI from svn (svn fetcher):

  SRC_URI = "svn://svn.savannah.nongnu.org/svn/avrdude/;protocol=http;module=trunk;rev=1429 \
          "
  S = "${WORKDIR}/trunk/avrdude"
  

Specify the dependencies

• Compile-time dependencies (the ones suffixed with -native are supposed to run on the build-host, the ones without the native suffix are for the target) - DEPENDS:

  DEPENDS = "glib-2.0-native libtool-native intltool-native curl glib-2.0 goocanvas"
  

• Runtime dependencies - RDEPENDS:

  RDEPENDS:${PN} = "bash perl python"    # syntax for "Honister" or newer releases
  RDEPENDS_${PN} = "bash perl python"    # syntax for releases older than "Honister"
  

• Runtime preferred packages (not necessary for the program to run, but nice-to-have packages that provide additional functionality) - RRECOMMENDS:

  RRECOMMENDS:${PN} = "ntpdate alsa-utils-alsamixer"    # syntax for "Honister" or newer releases
  RRECOMMENDS_${PN} = "ntpdate alsa-utils-alsamixer"    # syntax for releases older than "Honister"
  

Specify the license file

• License in a file (LIC_FILES_CHKSUM):

  LIC_FILES_CHKSUM = "file://LICENSE;md5=a5ec40cafba26fc4396d0b550f824e01"
  

• License as part of a file (LIC_FILES_CHKSUM):

  LIC_FILES_CHKSUM = "file://zlib.h;beginline=6;endline=23;md5=5377232268e952e9ef63bc555f7aa6c0"
  

Patching recipes

• Make a simple bbappend file:

  FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"    # syntax for "Honister" or newer releases
  SRC_URI += " \
        file://patch1.patch \
        "
  

• Snippet for adding an intermediate build step inside a bitbake recipe:

  do_more_patching() {
    patch -d ${S} -p1 < ${WORKDIR}/foo/bar.patch
  }
  addtask do_more_patching after do_unpack before do_patch
  

• Refresh a patch:

  devtool modify <recipe_name>
  devtool finish --force-patch-refresh <recipe_name> <layer_path>